// Author: David Soto-Oñate and  Brais Suárez-Eiroa
// Project: ARCA
// Aim: Municipal GHG estimation
// Last version:  01/10/2025

version 11.0
clear all
capture log close
set more off

*set logtype text
cd "C:\...\ARCA_Informe_datos_stata_v20251001\stata\consumo_ccaa\" //sustituir por directorio local
log using consumo_ccaa.log, replace 
di "log file printed on $S_DATE at $S_TIME"

//Datos de origen e inspección
sysuse consumo_ccaa_raw_2023.dta


* 1. Cálculo de consumos no asignados a categorías de producto
bysort ccaa_code: egen gasto_revelado=total(gasto_prod_pc_2023)
gen gasto_no_revelado=gasto_total_ccaa_2023-gasto_revelado

* 2. Cálculo de proporción del producto faltante en región con respecto a sumatorio de proporción de productos no asignados en la región. Usamos proporciones estatales como referencia

bysort ccaa_code: egen total_gasto_no_revelado = total(gasto_prod_pc_espana_2023) if gasto_prod_pc_2023==.

gen prop_no_revelado=gasto_prod_pc_espana_2023/total_gasto_no_revelado  if gasto_prod_pc_2023==.

gen consumo_tratado=gasto_prod_pc_2023
replace consumo_tratado=prop_no_revelado*gasto_no_revelado if gasto_prod_pc_2023==.

	**** Para obtener tabla de excel GastoPC_CCAA_4, 
	{
	* activar este código eliminando "/*" y "*/". Tras la consulta, restablecezca el 
	* código y vuelva a correr el programa.
	/*
	keep ccaa_code consumo_tratado prod_code_4
	reshape wide consumo_tratado, i(prod_code_4) j(ccaa_code)
	*/
	}



*
* 3. Ajuste por impuestos y vivienda
gen consumo_ccaa_4= consumo_tratado*index_impuestos*index_vivienda

	**** Para obtener tabla de excel GastoPC_CCAA_4_corregido,
	{
	* activar este código eliminando "/*" y "*/". Tras la consulta, restablecezca el 
	* código y vuelva a correr el programa.
	/*
	keep ccaa_code consumo_ccaa_4 prod_code_4
	reshape wide consumo_ccaa_4, i(prod_code_4) j(ccaa_code)
	*/
	}


*
* 4. Agregación del gasto al nivel de 3 dígitos
bysort prod_code_3 ccaa_code: egen consumo_ccaa_3= total(consumo_ccaa_4)

* 5. Nos quedamos con el nivel de producto de 3 dígitos y creamos archivo consumo_ccaa.dta
bysort prod_code_3 ccaa_code: gen id=_n
keep if id==1

drop id prod_code_4 prod_name_4 consumo_ccaa_4
rename consumo_ccaa_3 consumo_ccaa

keep prod_code_3 prod_name_3 ccaa_code ccaa_name consumo_ccaa

save consumo_ccaa


	**** Para obtener tabla de excel GastoPC_CCAA_3,
	* activar este código eliminando "/*" y "*/". 
	{
	/*
	keep ccaa_code consumo_ccaa prod_code_3
	reshape wide consumo_ccaa, i(prod_code_3) j(ccaa_code)
	*/
	}

